हिन्दी
INR
लोकप्रिय
अन्य
QuarkChain
QuarkChain
ICO
P2P Transactional System
श्रेणी: भूमिकारूप व्यवस्था, अन्य
स्थापित: 2 जून 2018
देश: United States
Sadly, you’ve exceeded the limit of adding to favorite.
The limit possible is 5
Increase the limit
वेबसाइट पर जाएं

ICO के बारे में जानकारी

मंच Ethereum
स्वीकार किए जाते हैं ETH
आरंभ करने की तिथि 2 जून 2018
अंतिम तिथि 3 जून 2018
टोकन मूल्य 1 QKC =
टोकन जारी किया 10 000 000 000
मुलायम टोपी
सख्त टोपी
बढ़ाया
न्यूनतम राशि 0 QKC
टोकन QKC - 0.0227441844$ व्यापार
काल
02.06.2018 03.06.2018
100.00%
QuarkChain (QKC)
QuarkChain (QKC)
Token
Ethereum
Utility
ERC-20
Platform: Ethereum
व्यापार -
स्मार्ट अनुबंध - QuarkChain
pragma solidity ^0.4.13;

contract Ownable {
  address public owner;


  event OwnershipRenounced(address indexed previousOwner);
  event OwnershipTransferred(
    address indexed previousOwner,
    address indexed newOwner
  );


  /**
   * @dev The Ownable constructor sets the original `owner` of the contract to the sender
   * account.
   */
  constructor() public {
    owner = msg.sender;
  }

  /**
   * @dev Throws if called by any account other than the owner.
   */
  modifier onlyOwner() {
    require(msg.sender == owner);
    _;
  }

  /**
   * @dev Allows the current owner to transfer control of the contract to a newOwner.
   * @param newOwner The address to transfer ownership to.
   */
  function transferOwnership(address newOwner) public onlyOwner {
    require(newOwner != address(0));
    emit OwnershipTransferred(owner, newOwner);
    owner = newOwner;
  }

  /**
   * @dev Allows the current owner to relinquish control of the contract.
   */
  function renounceOwnership() public onlyOwner {
    emit OwnershipRenounced(owner);
    owner = address(0);
  }
}

contract Pausable is Ownable {
  event Pause();
  event Unpause();

  bool public paused = false;


  /**
   * @dev Modifier to make a function callable only when the contract is not paused.
   */
  modifier whenNotPaused() {
    require(!paused);
    _;
  }

  /**
   * @dev Modifier to make a function callable only when the contract is paused.
   */
  modifier whenPaused() {
    require(paused);
    _;
  }

  /**
   * @dev called by the owner to pause, triggers stopped state
   */
  function pause() onlyOwner whenNotPaused public {
    paused = true;
    emit Pause();
  }

  /**
   * @dev called by the owner to unpause, returns to normal state
   */
  function unpause() onlyOwner whenPaused public {
    paused = false;
    emit Unpause();
  }
}

contract ERC20Basic {
  function totalSupply() public view returns (uint256);
  function balanceOf(address who) public view returns (uint256);
  function transfer(address to, uint256 value) public returns (bool);
  event Transfer(address indexed from, address indexed to, uint256 value);
}

contract BasicToken is ERC20Basic {
  using SafeMath for uint256;

  mapping(address => uint256) balances;

  uint256 totalSupply_;

  /**
  * @dev total number of tokens in existence
  */
  function totalSupply() public view returns (uint256) {
    return totalSupply_;
  }

  /**
  * @dev transfer token for a specified address
  * @param _to The address to transfer to.
  * @param _value The amount to be transferred.
  */
  function transfer(address _to, uint256 _value) public returns (bool) {
    require(_to != address(0));
    require(_value <= balances[msg.sender]);

    balances[msg.sender] = balances[msg.sender].sub(_value);
    balances[_to] = balances[_to].add(_value);
    emit Transfer(msg.sender, _to, _value);
    return true;
  }

  /**
  * @dev Gets the balance of the specified address.
  * @param _owner The address to query the the balance of.
  * @return An uint256 representing the amount owned by the passed address.
  */
  function balanceOf(address _owner) public view returns (uint256) {
    return balances[_owner];
  }

}

contract ERC20 is ERC20Basic {
  function allowance(address owner, address spender)
    public view returns (uint256);

  function transferFrom(address from, address to, uint256 value)
    public returns (bool);

  function approve(address spender, uint256 value) public returns (bool);
  event Approval(
    address indexed owner,
    address indexed spender,
    uint256 value
  );
}

contract StandardToken is ERC20, BasicToken {

  mapping (address => mapping (address => uint256)) internal allowed;


  /**
   * @dev Transfer tokens from one address to another
   * @param _from address The address which you want to send tokens from
   * @param _to address The address which you want to transfer to
   * @param _value uint256 the amount of tokens to be transferred
   */
  function transferFrom(
    address _from,
    address _to,
    uint256 _value
  )
    public
    returns (bool)
  {
    require(_to != address(0));
    require(_value <= balances[_from]);
    require(_value <= allowed[_from][msg.sender]);

    balances[_from] = balances[_from].sub(_value);
    balances[_to] = balances[_to].add(_value);
    allowed[_from][msg.sender] = allowed[_from][msg.sender].sub(_value);
    emit Transfer(_from, _to, _value);
    return true;
  }

  /**
   * @dev Approve the passed address to spend the specified amount of tokens on behalf of msg.sender.
   *
   * Beware that changing an allowance with this method brings the risk that someone may use both the old
   * and the new allowance by unfortunate transaction ordering. One possible solution to mitigate this
   * race condition is to first reduce the spender's allowance to 0 and set the desired value afterwards:
   * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
   * @param _spender The address which will spend the funds.
   * @param _value The amount of tokens to be spent.
   */
  function approve(address _spender, uint256 _value) public returns (bool) {
    allowed[msg.sender][_spender] = _value;
    emit Approval(msg.sender, _spender, _value);
    return true;
  }

  /**
   * @dev Function to check the amount of tokens that an owner allowed to a spender.
   * @param _owner address The address which owns the funds.
   * @param _spender address The address which will spend the funds.
   * @return A uint256 specifying the amount of tokens still available for the spender.
   */
  function allowance(
    address _owner,
    address _spender
   )
    public
    view
    returns (uint256)
  {
    return allowed[_owner][_spender];
  }

  /**
   * @dev Increase the amount of tokens that an owner allowed to a spender.
   *
   * approve should be called when allowed[_spender] == 0. To increment
   * allowed value is better to use this function to avoid 2 calls (and wait until
   * the first transaction is mined)
   * From MonolithDAO Token.sol
   * @param _spender The address which will spend the funds.
   * @param _addedValue The amount of tokens to increase the allowance by.
   */
  function increaseApproval(
    address _spender,
    uint _addedValue
  )
    public
    returns (bool)
  {
    allowed[msg.sender][_spender] = (
      allowed[msg.sender][_spender].add(_addedValue));
    emit Approval(msg.sender, _spender, allowed[msg.sender][_spender]);
    return true;
  }

  /**
   * @dev Decrease the amount of tokens that an owner allowed to a spender.
   *
   * approve should be called when allowed[_spender] == 0. To decrement
   * allowed value is better to use this function to avoid 2 calls (and wait until
   * the first transaction is mined)
   * From MonolithDAO Token.sol
   * @param _spender The address which will spend the funds.
   * @param _subtractedValue The amount of tokens to decrease the allowance by.
   */
  function decreaseApproval(
    address _spender,
    uint _subtractedValue
  )
    public
    returns (bool)
  {
    uint oldValue = allowed[msg.sender][_spender];
    if (_subtractedValue > oldValue) {
      allowed[msg.sender][_spender] = 0;
    } else {
      allowed[msg.sender][_spender] = oldValue.sub(_subtractedValue);
    }
    emit Approval(msg.sender, _spender, allowed[msg.sender][_spender]);
    return true;
  }

}

contract PausableToken is StandardToken, Pausable {

  function transfer(
    address _to,
    uint256 _value
  )
    public
    whenNotPaused
    returns (bool)
  {
    return super.transfer(_to, _value);
  }

  function transferFrom(
    address _from,
    address _to,
    uint256 _value
  )
    public
    whenNotPaused
    returns (bool)
  {
    return super.transferFrom(_from, _to, _value);
  }

  function approve(
    address _spender,
    uint256 _value
  )
    public
    whenNotPaused
    returns (bool)
  {
    return super.approve(_spender, _value);
  }

  function increaseApproval(
    address _spender,
    uint _addedValue
  )
    public
    whenNotPaused
    returns (bool success)
  {
    return super.increaseApproval(_spender, _addedValue);
  }

  function decreaseApproval(
    address _spender,
    uint _subtractedValue
  )
    public
    whenNotPaused
    returns (bool success)
  {
    return super.decreaseApproval(_spender, _subtractedValue);
  }
}

contract DetailedERC20 is ERC20 {
  string public name;
  string public symbol;
  uint8 public decimals;

  constructor(string _name, string _symbol, uint8 _decimals) public {
    name = _name;
    symbol = _symbol;
    decimals = _decimals;
  }
}

contract QuarkChainToken is DetailedERC20, PausableToken {

    using SafeMath for uint256;

    // One time switch to enable token transferability.
    bool public transferable = false;

    // Record private sale wallet to allow transfering.
    address public privateSaleWallet;

    // Crowdsale contract address set externally.
    address public crowdsaleAddress;

    // 10 billion tokens, 18 decimals.
    uint public constant INITIAL_SUPPLY = 1e28;

    modifier onlyWhenTransferEnabled() {
        if (!transferable) {
            require(msg.sender == owner || msg.sender == crowdsaleAddress || msg.sender == privateSaleWallet);
        }
        _;
    }

    modifier validDestination(address to) {
        require(to != address(this));
        _;
    }

    constructor() public DetailedERC20("QuarkChain Token", "QKC", 18) {
        totalSupply_ = INITIAL_SUPPLY;
    }

    /// @dev Override to only allow tranfer after being switched on.
    function transferFrom(address _from, address _to, uint256 _value)
        public
        validDestination(_to)
        onlyWhenTransferEnabled
        returns (bool)
    {
        return super.transferFrom(_from, _to, _value);
    }

    /// @dev Override to only allow tranfer after being switched on.
    function transfer(address _to, uint256 _value)
        public
        validDestination(_to)
        onlyWhenTransferEnabled
        returns (bool)
    {
        return super.transfer(_to, _value);
    }

    /**
     * @dev One-time switch to enable transfer.
     */
    function enableTransfer() external onlyOwner {
        transferable = true;
    }

    /**
     * @dev Run this before crowdsale begins, so crowdsale contract could transfer tokens.
     */
    function setCrowdsaleAddress(address _crowdsaleAddress) external onlyOwner {
        // Can only set one time.
        require(crowdsaleAddress == 0x0);
        require(_crowdsaleAddress != 0x0);
        crowdsaleAddress = _crowdsaleAddress;
        balances[crowdsaleAddress] = INITIAL_SUPPLY;
    }

    /**
     * @dev Run this before crowdsale begins, so private sale wallet could transfer tokens.
     */
    function setPrivateSaleAddress(address _privateSaleWallet) external onlyOwner {
        // Can only set one time.
        require(privateSaleWallet == 0x0);
        privateSaleWallet = _privateSaleWallet;
    }

}

library SafeMath {

  /**
  * @dev Multiplies two numbers, throws on overflow.
  */
  function mul(uint256 a, uint256 b) internal pure returns (uint256 c) {
    if (a == 0) {
      return 0;
    }
    c = a * b;
    assert(c / a == b);
    return c;
  }

  /**
  * @dev Integer division of two numbers, truncating the quotient.
  */
  function div(uint256 a, uint256 b) internal pure returns (uint256) {
    // assert(b > 0); // Solidity automatically throws when dividing by 0
    // uint256 c = a / b;
    // assert(a == b * c + a % b); // There is no case in which this doesn't hold
    return a / b;
  }

  /**
  * @dev Subtracts two numbers, throws on overflow (i.e. if subtrahend is greater than minuend).
  */
  function sub(uint256 a, uint256 b) internal pure returns (uint256) {
    assert(b <= a);
    return a - b;
  }

  /**
  * @dev Adds two numbers, throws on overflow.
  */
  function add(uint256 a, uint256 b) internal pure returns (uint256 c) {
    c = a + b;
    assert(c >= a);
    return c;
  }
}
Bitcoin
(-1.50%)
Ethereum
(-2.96%)
Binance Coin
(-2.24%)
Ripple
(2.04%)
Cardano
(-4.10%)
HexCoin
(8.51%)
Polkadot
(-5.44%)
Dogecoin
(2.15%)
Litecoin
(1.99%)
Bitcoin Cash
(-4.43%)
ChainLink
(-0.81%)
Stellar
(4.48%)
Luna
(-1.33%)
Avalanche
(1.97%)
Tether
(0.09%)
Ethereum Classic
(0.60%)
Cosmos
(3.02%)
Tron
(-1.46%)
EOS
(2.57%)
Vechain
(-2.69%)
Support Center
Tracking of cryptocurrency markets has become even more convenient with our application.
Neironix मोबाइल ऐप
मुफ्त में डाउनलोड करें
Download App
खाता बनाएं
साइन इन करें
तकनीकी सहायता से संपर्क करें
यदि आपको सिस्टम में कोई समस्या है, तो कृपया नीचे दिए गए फॉर्म में समस्या का वर्णन करें, या अपना प्रश्न भेजें: support@neironix.io